fms_string_utils.inc

!***********************************************************************
!*                             Apache License 2.0
!*
!* This file is part of the GFDL Flexible Modeling System (FMS).
!*
!* Licensed under the Apache License, Version 2.0 (the "License");
!* you may not use this file except in compliance with the License.
!* You may obtain a copy of the License at
!*
!*     http://www.apache.org/licenses/LICENSE-2.0
!*
!* FMS is distributed in the hope that it will be useful, but WITHOUT
!* WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied;
!* without even the implied warranty of MERCHANTABILITY or FITNESS FOR A
!* PARTICULAR PURPOSE. See the License for the specific language
!* governing permissions and limitations under the License.
!***********************************************************************
 
!> @brief Converts a 1D array of real numbers to a string
!> @return The 1D array as a string
function stringify_1d_(arr, fmt)
  real(STRING_UTILS_KIND_), dimension(:), intent(in) :: arr !< Real array to be converted to a string
  character(*), intent(in), optional :: fmt !< Optional format string for the real array entries
  character(:), allocatable :: STRINGIFY_1D_
  integer :: i, n
 
  n = size(arr)
 
  if (n .gt. 0) then
    stringify_1d_ = "[" // string(arr(1), fmt)
  else
    stringify_1d_ = "["
  endif
 
  do i = 2,n
    stringify_1d_ = stringify_1d_ // ", " // string(arr(i), fmt)
  enddo
 
  stringify_1d_ = stringify_1d_ // "]"
end function
 
!> @brief Converts a 2D array of real numbers to a string
!> @return The 2D array as a string
function stringify_2d_(arr, fmt)
  real(STRING_UTILS_KIND_), dimension(:,:), intent(in) :: arr !< Real array to be converted to a string
  character(*), intent(in), optional :: fmt !< Optional format string for the real array entries
  character(:), allocatable :: STRINGIFY_2D_
  integer :: i, n
 
  n = size(arr, 2)
 
  if (n .gt. 0) then
    stringify_2d_ = "[" // stringify_1d_(arr(:,1), fmt)
  else
    stringify_2d_ = "["
  endif
 
  do i = 2,n
    stringify_2d_ = stringify_2d_ // ", " // stringify_1d_(arr(:,i), fmt)
  enddo
 
  stringify_2d_ = stringify_2d_ // "]"
end function
 
!> @brief Converts a 3D array of real numbers to a string
!> @return The 3D array as a string
function stringify_3d_(arr, fmt)
  real(STRING_UTILS_KIND_), dimension(:,:,:), intent(in) :: arr !< Real array to be converted to a string
  character(*), intent(in), optional :: fmt !< Optional format string for the real array entries
  character(:), allocatable :: STRINGIFY_3D_
  integer :: i, n
 
  n = size(arr, 3)
 
  if (n .gt. 0) then
    stringify_3d_ = "[" // stringify_2d_(arr(:,:,1), fmt)
  else
    stringify_3d_ = "["
  endif
 
  do i = 2,n
    stringify_3d_ = stringify_3d_ // ", " // stringify_2d_(arr(:,:,i), fmt)
  enddo
 
  stringify_3d_ = stringify_3d_ // "]"
end function